GALERIE     EN COURS     SCENES     MACROS     GUIDE     PORTFOLIO     A PROPOS


Mathématiques appliquées
Introduction

"Mathématiques appliquées"... en fait plutôt, la manière d'utiliser POVRay pour produire des images de qualités de courbes et de de surfaces en 3 dimensions. Bien que rien ne soit prévu à cet effet, POVRay est suffisament puissant et versatile pour remplir facilement cette tâche.



Rappel

Si vous avez lu mon guide sur POVRAY, vous devez vous rappeler que les axes sont orientés d'une manière particulière : l'axe Y est vertical, les axes X et Z sont dans le plan horizontal. Cela peut surprendre au début les non-habitués de POVRay. On peut donc soit s'accomoder de ce fait, soit procéder à des changements de variables : permutation des Y et des Z. Il existe aussi une option dans la définition de la caméa, mais nous en parlerons plus tard.
Utilisation pratique.

Toute des images que vous allez découvrir par la suite sont faites à partir de cette base qui vous permet de mettre en place l'image, les axes et un quadrillage horizontal.
La scène vide permet donc de produire cette image :
image de base
Script :

// --------------------------------------------------------------------------
#version unofficial MegaPov 1.21;


// --------------------------------------------------------------------------
// --- INCLUDES -------------------------------------------------------------
// --------------------------------------------------------------------------
#include "colors.inc"
#include "myMacros.inc"

#declare displayAxis = true;

// --------------------------------------------------------------------------
// --- SCENE ----------------------------------------------------------------
// --------------------------------------------------------------------------
global_settings {
  assumed_gamma 1.80
  max_trace_level 10
  }

camera {
  location p2r(40, 25, 30,false)
  look_at <0, 1, 0>
  angle 36
  }

light_source {
  p2r(45, 45, 1000,false)
  color White
  }
background {
  color White*0.00
  }

#declare courbeFinish = finish {
  ambient 0.40
  diffuse 0.60
  phong 0.85
  brilliance 2
  };

#if (displayAxis)
  #declare axisLen = 12;
  drawAxis (axisLen+1, 0.05)
  
  #declare index = -axisLen*0.50;
  #while ( index <= +axisLen*0.50 )
    cylinder {
      < index, 0, -axisLen*0.50 >
      < index, 0, +axisLen*0.50 >
      0.01
      pigment { color White*0.80}
      finish { courbeFinish }
      }
    #set index = index + 1;
  #end
  
  #set index = -axisLen*0.50;
  #while ( index <= +axisLen*0.50 )
    cylinder {
      < -axisLen*0.50, 0, index >,
      < +axisLen*0.50, 0, index >,
      0.01
      pigment { color White*0.80 }
      finish { courbeFinish }
      }
    #set index=index+1;
  #end
  
  #declare deltaT = axisLen*0.60;
  text {
    ttf "crystal.ttf", "X" 0.15, <0.0, 0.0, 0.0>
    h_align_center
    translate deltaT*x
    pigment { color Red }
    finish { courbeFinish }
    }
  text {
    ttf "crystal.ttf", "Y" 0.15, <0.0, 0.0, 0.0>
    h_align_center
    rotate +45*y
    translate deltaT*y
    pigment { color Green }
    finish { courbeFinish }
    }
  text {
    ttf "crystal.ttf", "Z" 0.15, <0.0, 0.0, 0.0>
    h_align_center
    rotate -90*y
    translate deltaT*z
    pigment { color Blue }
    finish { courbeFinish }
    }
#end
Ensuite, on ajoute le code propreà chaque courbe.
Références mathématiques sur les courbes : Encyclopédie des formes mathématiques remarquables de Robert Ferréol.


Afin de conserver une petite taille pour les fichiers images, celles-ci sont compressées au format jpeg. La qualité s'en resent un peu mais, rassurez-vous, vous obtiendrez à partir de POVRay des images d'excellente qualitée au format png, ppm ou pict. Vous pouvez télécharger une archive zip contenant toutes les images 640 x 480 au format png (828Ko).

Bon, maintenant des exemples sur les pages suivantes et bonne découverte ...